Example Script - How to Open a MySQL Database
<MIVA STANDARDOUTPUTLEVEL = "text, html, compresswhitespace" ERROROUTPUTLEVEL = "syntax, expression, runtime">
<MvCOMMENT>
|
| SQL Open Database
|
| Version: 5.002
| 09/01/2006
|
| file: sql_open_database.mvc
|
| Developed By:
| Lance Turner
| latu.net
| http://www.latu.net
| support@latu.net
|
| All files and source code contained herein are the property of latu.net.
| latu.net grants to the Licensee a nonexclusive, nontransferable license
| to use the script, library and other included scripts and files.
| Distribution of this file or portions of this file for other uses is not
| allowed without the prior agreement of the developer.
|
| Copyright 2006 Lance Turner, latu.net. All rights reserved.
|
</MvCOMMENT>
<MvCOMMENT>
---------------------------------------------------------------------
Database Variables:
DB_Type
DB_Database
DB_Username
DB_Password
DB_Flags
Example of DB Record:
mysql|database@yourdomain.com|user1234|pass1234|
---------------------------------------------------------------------
</MvCOMMENT>
<MvCOMMENT>
---------------------------------------------------------------------
Initialize Variables
---------------------------------------------------------------------
</MvCOMMENT>
<MvASSIGN NAME = "l.db_dat" VALUE = "{ '/db.dat' }">
<MvCOMMENT>
---------------------------------------------------------------------
---------------------------------------------------------------------
</MvCOMMENT>
<MvIFDEF NAME="DEBUG">
<MvEVAL EXPR="{ 'SQL Open Database<br>' }">
</MvIFDEF>
<MvASSIGN NAME = "l.ok" VALUE = "{ Initialize_DB_Vars(l.db_dat) }">
<MvIF EXPR = "{ l.ok }">
<MvIFDEF NAME="DEBUG">
<MvEVAL EXPR="{ 'g.DB:Type: ' $ g.DB:Type $ '<br>' }">
<MvEVAL EXPR="{ 'g.DB:Database: ' $ g.DB:Database $ '<br>' }">
<MvEVAL EXPR="{ 'g.DB:Username: ' $ g.DB:Username $ '<br>' }">
</MvIFDEF>
<MvOPEN NAME = "Merchant"
DATABASE = "{ g.DB:Database }"
USERNAME = "{ g.DB:Username }"
PASSWORD = "{ g.DB:Password }"
TYPE = "{ g.DB:Type }">
<MvIF EXPR = "{ NOT g.MvOPEN_Error }">
<MvASSIGN NAME = "g.Data_Opened" VALUE = "{ 1 }">
<MvIFDEF NAME="DEBUG">
<MvEVAL EXPR="{ 'Database Opened' $ '<br>' }">
</MvIFDEF>
<MvELSE>
<MvASSIGN NAME = "l.ok" VALUE = "{ 0 }">
<MvIFDEF NAME="DEBUG">
<MvEVAL EXPR="{ 'g.MvOPEN_Error: ' $ g.MvOPEN_Error $ '<br>' }">
</MvIFDEF>
</MvIF>
</MvIF>
<MvIFDEF NAME="DEBUG">
<MvEVAL EXPR="{ 'g.Data_Opened: ' $ g.Data_Opened $ '<br>' }">
</MvIFDEF>
<MvEXIT>
<MvFUNCTION NAME = "Initialize_DB_Vars" PARAMETERS = "db_dat" STANDARDOUTPUTLEVEL = "" ERROROUTPUTLEVEL = "">
<MvASSIGN NAME = "l.ok" VALUE = "{ 1 }">
<MvIFDEF NAME="DEBUG">
<MvEVAL EXPR="{ 'Initialize DB Vars' $ '<br>' }">
<MvEVAL EXPR="{ 'db data file: ' $ l.db_dat $ '<br>' }">
</MvIFDEF>
<MvIMPORT FILE="{ l.db_dat }" FIELDS="db_type,db_database,db_username,db_password" DELIMITER="|">
</MvIMPORT>
<MvIF EXPR = "{ g.MvIMPORT_ERROR }">
<MvIFDEF NAME="DEBUG">
<MvEVAL EXPR="{ 'g.MvIMPORT_ERROR: ' $ g.MvIMPORT_ERROR $ '<br>' }">
</MvIFDEF>
<MvASSIGN NAME = "l.ok" VALUE = "{ 0 }">
<MvELSE>
<MvIFDEF NAME="DEBUG">
<MvEVAL EXPR="{ 'DB Vars Imported' $ '<br>' }">
</MvIFDEF>
<MvIF EXPR = "{ len(db_type) }">
<MvASSIGN NAME = "g.DB:Type" VALUE = "{ db_type }">
<MvELSE>
<MvASSIGN NAME = "l.ok" VALUE = "{ 0 }">
</MvIF>
<MvIF EXPR = "{ len(db_database) }">
<MvASSIGN NAME = "g.DB:Database" VALUE = "{ db_database }">
<MvELSE>
<MvASSIGN NAME = "l.ok" VALUE = "{ 0 }">
</MvIF>
<MvIF EXPR = "{ len(DB_Username) }">
<MvASSIGN NAME = "g.DB:Username" VALUE = "{ db_username }">
<MvELSE>
<MvASSIGN NAME = "l.ok" VALUE = "{ 0 }">
</MvIF>
<MvIF EXPR = "{ len(DB_Password) }">
<MvASSIGN NAME = "g.DB:Password" VALUE = "{ db_password }">
<MvELSE>
<MvASSIGN NAME = "l.ok" VALUE = "{ 0 }">
</MvIF>
</MvIF>
<MvFUNCTIONRETURN VALUE = "{ l.ok }">
</MvFUNCTION>
|
